[AS3] 簡單講客製 Event (2)

一般的使用只需要繼承自 flash.events.Event，
並且覆寫 clone 這個 function

package events
{
import flash.events.Event;

public class CustomEvent extends Event
{
public var data:Object; // 喜歡什麼都可以自己加~~當然也可以用 getter & setter 宣告
public function CustomEvent( type:String , data:Object )
{
super(type);
this.data = data;
}
override public function clone():Event {
return new CustomEvent( type , data );
}
}
}
如果你的 Event 需要 bubbles 請修改：
super( type , true )

方便 debug 版本，就是多一個覆寫 toString function
package events
{
import flash.events.Event;

public class Custom2Event extends Event
{
public var output:String;
public static const UPDATE_OUTPUT:String = "update_output";
public function Custom2Event( type:String , output:String)
{
super(type);
this.output = output;
}
override public function clone():Event {
return new Custom2Event( type , output );
}
override public function toString():String {
//印出你想要看的資訊
return formatToString("Custom2Event", "type" , "output" );
}
}
}


簡單的測試一下....TestEvent.as
package
{
import events.Custom2Event;
import fl.controls.Button;
import flash.display.Sprite;
import flash.events.MouseEvent;

/**
* TestEvent
* @author Erin
*/
public class TestEvent extends Sprite
{
public function TestEvent()
{
var btn:Button = new Button;
addChild( btn );
btn.addEventListener(MouseEvent.CLICK, onClick);
addEventListener( Custom2Event.UPDATE_OUTPUT, onCustomEvent );
}
private function onClick(e:MouseEvent):void {
dispatchEvent(new Custom2Event( Custom2Event.UPDATE_OUTPUT , "lalala"));
}
private function onCustomEvent(e:Custom2Event):void {
trace(e);
}
}
}

output : [Custom2Event type="update_output" output="lalala"]